Função que retorna o xml de uma nota em AdvPL

Olá pessoal…

Hoje vou mostrar uma função que desenvolvi, que retorna o xml de uma nota transmitida ou cancelada via AdvPL.

AdvPL

A função utiliza recursos do TSS para carregar e criar o arquivo xml, é necessário apenas informar, o número da nota, a série, e o caminho para geração do arquivo xml.

Abaixo a função desenvolvida:

//Bibliotecas
#Include "Protheus.ch"
   
/*/{Protheus.doc} zSpedXML
Função que gera o arquivo xml da nota (normal ou cancelada) através do documento e da série disponibilizados
@author Atilio
@since 25/07/2017
@version 1.0
@param cDocumento, characters, Código do documento (F2_DOC)
@param cSerie, characters, Série do documento (F2_SERIE)
@param cArqXML, characters, Caminho do arquivo que será gerado (por exemplo, C:\TOTVS\arquivo.xml)
@param lMostra, logical, Se será mostrado mensagens com os dados (erros ou a mensagem com o xml na tela)
@type function
@example Segue exemplo abaixo
    u_zSpedXML("000000001", "1", "C:\TOTVS\arquivo1.xml", .F.) //Não mostra mensagem com o XML
       
    u_zSpedXML("000000001", "1", "C:\TOTVS\arquivo2.xml", .T.) //Mostra mensagem com o XML
/*/
   
User Function zSpedXML(cDocumento, cSerie, cArqXML, lMostra)
    Local aArea        := GetArea()
    Local cURLTss      := PadR(GetNewPar("MV_SPEDURL","http://"),250)  
    Local oWebServ
    Local cIdEnt       := RetIdEnti()
    Local cTextoXML    := ""
    Default cDocumento := ""
    Default cSerie     := ""
    Default cArqXML    := GetTempPath()+"arquivo_"+cSerie+cDocumento+".xml"
    Default lMostra    := .F.
       
    //Se tiver documento
    If !Empty(cDocumento)
        cDocumento := PadR(cDocumento, TamSX3('F2_DOC')[1])
        cSerie     := PadR(cSerie,     TamSX3('F2_SERIE')[1])
           
        //Instancia a conexão com o WebService do TSS    
        oWebServ:= WSNFeSBRA():New()
        oWebServ:cUSERTOKEN        := "TOTVS"
        oWebServ:cID_ENT           := cIdEnt
        oWebServ:oWSNFEID          := NFESBRA_NFES2():New()
        oWebServ:oWSNFEID:oWSNotas := NFESBRA_ARRAYOFNFESID2():New()
        aAdd(oWebServ:oWSNFEID:oWSNotas:oWSNFESID2,NFESBRA_NFESID2():New())
        aTail(oWebServ:oWSNFEID:oWSNotas:oWSNFESID2):cID := (cSerie+cDocumento)
        oWebServ:nDIASPARAEXCLUSAO := 0
        oWebServ:_URL              := AllTrim(cURLTss)+"/NFeSBRA.apw" 
           
        //Se tiver notas
        If oWebServ:RetornaNotas()
           
            //Se tiver dados
            If Len(oWebServ:oWsRetornaNotasResult:OWSNOTAS:oWSNFES3) > 0
               
                //Se tiver sido cancelada
                If oWebServ:oWsRetornaNotasResult:OWSNOTAS:oWSNFES3[1]:oWSNFECANCELADA != Nil
                    cTextoXML := oWebServ:oWsRetornaNotasResult:OWSNOTAS:oWSNFES3[1]:oWSNFECANCELADA:cXML
                       
                //Senão, pega o xml normal
                Else
                    cTextoXML := oWebServ:oWsRetornaNotasResult:OWSNOTAS:oWSNFES3[1]:oWSNFE:cXML
                EndIf
                   
                //Gera o arquivo
                MemoWrite(cArqXML, cTextoXML)
                   
                //Se for para mostrar, será mostrado um aviso com o conteúdo
                If lMostra
                    Aviso("zSpedXML", cTextoXML, {"Ok"}, 3)
                EndIf
                   
            //Caso não encontre as notas, mostra mensagem
            Else
                ConOut("zSpedXML > Verificar parâmetros, documento e série não encontrados ("+cDocumento+"/"+cSerie+")...")
                   
                If lMostra
                    Aviso("zSpedXML", "Verificar parâmetros, documento e série não encontrados ("+cDocumento+"/"+cSerie+")...", {"Ok"}, 3)
                EndIf
            EndIf
           
        //Senão, houve erros na classe
        Else
            ConOut("zSpedXML > "+IIf(Empty(GetWscError(3)), GetWscError(1), GetWscError(3))+"...")
               
            If lMostra
                Aviso("zSpedXML", IIf(Empty(GetWscError(3)), GetWscError(1), GetWscError(3)), {"Ok"}, 3)
            EndIf
        EndIf
    EndIf
    RestArea(aArea)
Return

Update Dezembro de 2021:

O grande Jorge Alberto ( LinkedIn ), fez uma contribuição para que seja exportado a tag NFeProc juntamente com a tag do XML principal, abaixo segue o exemplo (trecho alterado da linha 59 a 63):

//Bibliotecas
#Include "Protheus.ch"
   
/*/{Protheus.doc} zSpedXML
Função que gera o arquivo xml da nota (normal ou cancelada) através do documento e da série disponibilizados
@author Atilio
@since 25/07/2017
@version 1.0
@param cDocumento, characters, Código do documento (F2_DOC)
@param cSerie, characters, Série do documento (F2_SERIE)
@param cArqXML, characters, Caminho do arquivo que será gerado (por exemplo, C:\TOTVS\arquivo.xml)
@param lMostra, logical, Se será mostrado mensagens com os dados (erros ou a mensagem com o xml na tela)
@type function
@example Segue exemplo abaixo
    u_zSpedXML("000000001", "1", "C:\TOTVS\arquivo1.xml", .F.) //Não mostra mensagem com o XML
       
    u_zSpedXML("000000001", "1", "C:\TOTVS\arquivo2.xml", .T.) //Mostra mensagem com o XML
/*/
   
User Function zSpedXML(cDocumento, cSerie, cArqXML, lMostra)
    Local aArea        := GetArea()
    Local cURLTss      := PadR(GetNewPar("MV_SPEDURL","http://"),250)  
    Local oWebServ
    Local cIdEnt       := RetIdEnti()
    Local cTextoXML    := ""
    Default cDocumento := ""
    Default cSerie     := ""
    Default cArqXML    := GetTempPath()+"arquivo_"+cSerie+cDocumento+".xml"
    Default lMostra    := .F.
       
    //Se tiver documento
    If !Empty(cDocumento)
        cDocumento := PadR(cDocumento, TamSX3('F2_DOC')[1])
        cSerie     := PadR(cSerie,     TamSX3('F2_SERIE')[1])
           
        //Instancia a conexão com o WebService do TSS    
        oWebServ:= WSNFeSBRA():New()
        oWebServ:cUSERTOKEN        := "TOTVS"
        oWebServ:cID_ENT           := cIdEnt
        oWebServ:oWSNFEID          := NFESBRA_NFES2():New()
        oWebServ:oWSNFEID:oWSNotas := NFESBRA_ARRAYOFNFESID2():New()
        aAdd(oWebServ:oWSNFEID:oWSNotas:oWSNFESID2,NFESBRA_NFESID2():New())
        aTail(oWebServ:oWSNFEID:oWSNotas:oWSNFESID2):cID := (cSerie+cDocumento)
        oWebServ:nDIASPARAEXCLUSAO := 0
        oWebServ:_URL              := AllTrim(cURLTss)+"/NFeSBRA.apw" 
           
        //Se tiver notas
        If oWebServ:RetornaNotas()
           
            //Se tiver dados
            If Len(oWebServ:oWsRetornaNotasResult:OWSNOTAS:oWSNFES3) > 0
               
                //Se tiver sido cancelada
                If oWebServ:oWsRetornaNotasResult:OWSNOTAS:oWSNFES3[1]:oWSNFECANCELADA != Nil
                    cTextoXML := oWebServ:oWsRetornaNotasResult:OWSNOTAS:oWSNFES3[1]:oWSNFECANCELADA:cXML
                       
                //Senão, pega o xml normal (foi alterado abaixo conforme dica do Jorge Alberto)
                Else
                    cTextoXML := '<?xml version="1.0" encoding="UTF-8"?>'
                    cTextoXML += '<nfeProc xmlns="http://www.portalfiscal.inf.br/nfe" versao="4.00">'
                    cTextoXML += oWebServ:oWsRetornaNotasResult:OWSNOTAS:oWSNFES3[1]:oWSNFE:cXML
                    cTextoXML += oWebServ:oWsRetornaNotasResult:OWSNOTAS:oWSNFES3[1]:oWSNFE:cXMLPROT
                    cTextoXML += '</nfeProc>'
                EndIf
                   
                //Gera o arquivo
                MemoWrite(cArqXML, cTextoXML)
                   
                //Se for para mostrar, será mostrado um aviso com o conteúdo
                If lMostra
                    Aviso("zSpedXML", cTextoXML, {"Ok"}, 3)
                EndIf
                   
            //Caso não encontre as notas, mostra mensagem
            Else
                ConOut("zSpedXML > Verificar parâmetros, documento e série não encontrados ("+cDocumento+"/"+cSerie+")...")
                   
                If lMostra
                    Aviso("zSpedXML", "Verificar parâmetros, documento e série não encontrados ("+cDocumento+"/"+cSerie+")...", {"Ok"}, 3)
                EndIf
            EndIf
           
        //Senão, houve erros na classe
        Else
            ConOut("zSpedXML > "+IIf(Empty(GetWscError(3)), GetWscError(1), GetWscError(3))+"...")
               
            If lMostra
                Aviso("zSpedXML", IIf(Empty(GetWscError(3)), GetWscError(1), GetWscError(3)), {"Ok"}, 3)
            EndIf
        EndIf
    EndIf
    RestArea(aArea)
Return

Update Fevereiro de 2022:

O grande Josuel Silva ( LinkedIn ), fez uma adaptação no fonte para usar a classe FWFileWriter ao invés de MemoWrite, assim podendo usar a codificação UTF8. Segue abaixo:

//Bibliotecas
#Include "Protheus.ch"
   
/*/{Protheus.doc} zSpedXML
Função que gera o arquivo xml da nota (normal ou cancelada) através do documento e da série disponibilizados
@author Atilio
@since 25/07/2017
@version 1.0
@param cDocumento, characters, Código do documento (F2_DOC)
@param cSerie, characters, Série do documento (F2_SERIE)
@param cArqXML, characters, Caminho do arquivo que será gerado (por exemplo, C:\TOTVS\arquivo.xml)
@param lMostra, logical, Se será mostrado mensagens com os dados (erros ou a mensagem com o xml na tela)
@type function
@example Segue exemplo abaixo
    u_zSpedXML("000000001", "1", "C:\TOTVS\arquivo1.xml", .F.) //Não mostra mensagem com o XML
       
    u_zSpedXML("000000001", "1", "C:\TOTVS\arquivo2.xml", .T.) //Mostra mensagem com o XML
/*/
   
User Function zSpedXML(cDocumento, cSerie, cArqXML, lMostra)
    Local aArea        := GetArea()
    Local cURLTss      := PadR(GetNewPar("MV_SPEDURL","http://"),250)  
    Local oWebServ
    Local cIdEnt       := RetIdEnti()
    Local cTextoXML    := ""
	Local oFileXML
    Default cDocumento := ""
    Default cSerie     := ""
    Default cArqXML    := GetTempPath()+"arquivo_"+cSerie+cDocumento+".xml"
    Default lMostra    := .F.
       
    //Se tiver documento
    If !Empty(cDocumento)
        cDocumento := PadR(cDocumento, TamSX3('F2_DOC')[1])
        cSerie     := PadR(cSerie,     TamSX3('F2_SERIE')[1])
           
        //Instancia a conexão com o WebService do TSS    
        oWebServ:= WSNFeSBRA():New()
        oWebServ:cUSERTOKEN        := "TOTVS"
        oWebServ:cID_ENT           := cIdEnt
        oWebServ:oWSNFEID          := NFESBRA_NFES2():New()
        oWebServ:oWSNFEID:oWSNotas := NFESBRA_ARRAYOFNFESID2():New()
        aAdd(oWebServ:oWSNFEID:oWSNotas:oWSNFESID2,NFESBRA_NFESID2():New())
        aTail(oWebServ:oWSNFEID:oWSNotas:oWSNFESID2):cID := (cSerie+cDocumento)
        oWebServ:nDIASPARAEXCLUSAO := 0
        oWebServ:_URL              := AllTrim(cURLTss)+"/NFeSBRA.apw" 
           
        //Se tiver notas
        If oWebServ:RetornaNotas()
           
            //Se tiver dados
            If Len(oWebServ:oWsRetornaNotasResult:OWSNOTAS:oWSNFES3) > 0
               
                //Se tiver sido cancelada
                If oWebServ:oWsRetornaNotasResult:OWSNOTAS:oWSNFES3[1]:oWSNFECANCELADA != Nil
                    cTextoXML := oWebServ:oWsRetornaNotasResult:OWSNOTAS:oWSNFES3[1]:oWSNFECANCELADA:cXML
                       
                //Senão, pega o xml normal (foi alterado abaixo conforme dica do Jorge Alberto)
                Else
                    cTextoXML := '<?xml version="1.0" encoding="UTF-8"?>'
                    cTextoXML += '<nfeProc xmlns="http://www.portalfiscal.inf.br/nfe" versao="4.00">'
                    cTextoXML += oWebServ:oWsRetornaNotasResult:OWSNOTAS:oWSNFES3[1]:oWSNFE:cXML
                    cTextoXML += oWebServ:oWsRetornaNotasResult:OWSNOTAS:oWSNFES3[1]:oWSNFE:cXMLPROT
                    cTextoXML += '</nfeProc>'
                EndIf
                   
                //Gera o arquivo
				oFileXML := FWFileWriter():New(cArqXML, .T.)
				oFileXML:SetEncodeUTF8(.T.)
				oFileXML:Create()
				oFileXML:Write(cTextoXML)
				oFileXML:Close()
                   
                //Se for para mostrar, será mostrado um aviso com o conteúdo
                If lMostra
                    Aviso("zSpedXML", cTextoXML, {"Ok"}, 3)
                EndIf
                   
            //Caso não encontre as notas, mostra mensagem
            Else
                ConOut("zSpedXML > Verificar parâmetros, documento e série não encontrados ("+cDocumento+"/"+cSerie+")...")
                   
                If lMostra
                    Aviso("zSpedXML", "Verificar parâmetros, documento e série não encontrados ("+cDocumento+"/"+cSerie+")...", {"Ok"}, 3)
                EndIf
            EndIf
           
        //Senão, houve erros na classe
        Else
            ConOut("zSpedXML > "+IIf(Empty(GetWscError(3)), GetWscError(1), GetWscError(3))+"...")
               
            If lMostra
                Aviso("zSpedXML", IIf(Empty(GetWscError(3)), GetWscError(1), GetWscError(3)), {"Ok"}, 3)
            EndIf
        EndIf
    EndIf
    RestArea(aArea)
Return

Bom pessoal, por hoje é só.
Abraços e até a próxima.

Relacionado

Tags: AdvPL

5 de dezembro de 2017

Dan (Daniel Atilio)

Cristão de ramificação protestante. Especialista em Engenharia de Software pela FIB, graduado em Banco de Dados pela FATEC Bauru e técnico em informática pelo CTI da Unesp. Entusiasta de soluções Open Source e blogueiro nas horas vagas. Autor e mantenedor do portal Terminal de Informação.

William Correia disse:

2 de março de 2019 às 12:42 pm

Muito bom, obrigado por compartilhar seu conhecimento, estou aprendendo muito aqui no seu site.
Tem uma documentação completa sobre a WSNFeSBRA? ou como faço pra ver todos os Metodos dela?

Responder
- Dan_Atilio disse:
  
  6 de março de 2019 às 8:43 am
  
  Bom dia William, tudo bem?
  Por ser uma classe padrão, apenas a TOTVS possui a documentação dela, se você for um cliente, você pode solicitar por chamado. Mas não sei se passariam isso.
  Agora, se você for um analista da TOTVS, se tiver a chave de ouro, procure pelo .prx e no fonte padrão estará os métodos dela.
  Um grande abraço.
  
  Responder
Emerson Nascimento disse:

16 de julho de 2019 às 8:13 am

Não testei, mas achei sensacional pela simplicidade do código, pelo uso dos recursos da linguagem, sem reinvenção da “roda”. Obrigado por compartilhar.

Responder
- Dan_Atilio disse:
  
  23 de julho de 2019 às 3:10 pm
  
  Obrigado pelo feedback Emerson.
  Grande abraço jovem.
  
  Responder
André Felipe Loos disse:

27 de maio de 2020 às 5:04 pm

Boa tarde!
Estou precisando de uma função parecida, mas já tenho o XML e preciso gerar o PDF. Teria alguma opinião para o que pode ser feito?

Responder
- Dan_Atilio disse:
  
  28 de maio de 2020 às 5:28 am
  
  Bom dia André, tudo bem?
  Claro, o que você pode fazer, seria +- assim:
  1 – Criar uma tela de parâmetros com o caminho do xml de origem
  2 – No seu fonte, usar XMLParser / XMLParserFile para converter o texto em um objeto
  3 – Instanciar um FWMSPrinter em um objeto
  4 – Percorrer os nós do XML no objeto e imprimir no objeto de impressão
  
  Responder
GERALDO disse:

12 de agosto de 2020 às 8:23 am

Consigo gerar o XML mas vem sem PROTOCOLO DE AUTORIZAÇÃO DE USO ? Alguem com este problema nao consigo acertar o codigo…

Responder
- Dan_Atilio disse:
  
  16 de agosto de 2020 às 12:48 pm
  
  Então Geraldo, a função usa a conexão padrão do Protheus. A NFe já foi transmitida? Você está usando pelo SIGAADV ou SIGAMDI?
  
  Responder
GERALDO disse:

30 de setembro de 2020 às 9:16 am

SIGAMDI , VOU TESTAR PELO SIGAADV e sim ja trasmitida e autorizada quando uso o exportar padrao do TSS ele exporta correto … estava subindo novo release mas vou retomar este assunte mas por enquanto muito obrigado todos os posts aqui so Fera … Vlw

Responder
Vitor Saito disse:

13 de outubro de 2020 às 11:11 am

Bom dia Dan_Atilio! Utilizei seu fonte para efetuar o download do XML, porém, alguns XML’s não vem no padrão correto. Alguns ele baixa normalmente, mas outros vem com informações ‘cortadas’ e vem tudo em uma mesma linha. Quando abro em .TXT ele traz normalmente as informações. Pode me dizer o porquê? Obrigado.

Responder
- Dan_Atilio disse:
  
  16 de outubro de 2020 às 7:53 am
  
  Bom dia Vitor.
  O de trazer na mesma linha, é similar a você ir no Protheus, na tela de monitorar, pegar o schema e colar.
  Ai para quebrar as linhas, você pode usar um plugin no Notepad++, o XML Tools (opção Pretty Print XML With Line Breaks).
  Quanto ao conteúdo vir cortado, não sei te dizer, não peguei casos assim. Sempre corta com um número exato de caracteres?
  
  Responder
Thiago disse:

19 de fevereiro de 2021 às 11:34 am

Olá Danilo.

Teria alguma função para emitir NFs de entrada?
Essa só gera de NFs de saída.

Responder
- Dan_Atilio disse:
  
  20 de fevereiro de 2021 às 9:15 am
  
  Olá Thiago.
  Eu não possuo, mas meu amigo Súlivan tem uma solução para isso, veja – https://sulivansistemas.com/protheus-download-xml-sefaz/
  Ao entrar em contato com ele, fala que você veio pelo Terminal de Informação do Daniel Atilio. Pode ser que consiga um desconto.
  
  Responder
WILKER MARCAL FARIA COSTA disse:

22 de abril de 2021 às 10:23 am

Bom dia Dan_Atilio
Estou usando em um cliente a funcao que retorna o xml
e no meu caso esta gerando sem o protoloco de autorizacao.
debugando o fonte na classe que carrega o gera o xml, nao esta gerando com o protocolo mesmo
Tem ideia do que pode ser ?

Responder
- Dan_Atilio disse:
  
  23 de abril de 2021 às 8:10 am
  
  Bom dia Wilker.
  Se você fizer o processo manualmente funciona?
  Por exemplo, abrir o SIGAMDI, ir em Faturamento, Nfe Sefaz, Outras Ações, Monitorar, Inserir o número da Nota, clicar em outras ações, e depois clicar em Schema e salvar o XML. Dessa forma traz o protocolo?
  Abraços.
  
  Responder
Miziara disse:

24 de agosto de 2021 às 4:40 pm

Aos colegas que estão com o problema do xml ser gerado sem o protocolo de uso, substitua a linha 59 pelo trecho abaixo:
```
//Senão, pega o xml normal
                Else
                    cTextoXML := '<?xml version="1.0" encoding="UTF-8"?> <nfeProc xmlns="http://www.portalfiscal.inf.br/nfe" versao="4.00">'
                    cTextoXML += oWebServ:oWsRetornaNotasResult:OWSNOTAS:oWSNFES3[1]:oWSNFE:cXML
                    cTextoXML += oWebServ:oWsRetornaNotasResult:OWSNOTAS:oWSNFES3[1]:oWSNFE:cXMLPROT
                    cTextoXML += '</nfeProc>'
                EndIf
```
Responder
Guilherme Lopes disse:

24 de outubro de 2021 às 3:20 pm

Queria saber se tem algum parâmetro que pode ser informado para pesquisar no ambiente de de produção ou homologação

Responder
- Dan Atilio (Daniel Atilio) disse:
  
  27 de outubro de 2021 às 6:57 am
  
  Acho que não tem Guilherme, pois ele vai pegar as parametrizações da empresa logada (através do MV_SPEDURL).
  
  Responder
Josuel Silva disse:

25 de janeiro de 2022 às 1:45 pm

Fiz uma pequena alteração no fonte no momento da gravação substituído a função MemoWrite pela Classe FWFileWriter.
Desta forma, caso o XML contenha algum carácter UTF8, é possível setar a classe para gravar nesse formato e não deixar o XML inválido.

Alterado de :
MemoWrite(cArqXML, cTextoXML)

Para:

oFileXML := FWFileWriter():New(cArqXML, .T.)
oFileXML:SetEncodeUTF8(.T.)
oFileXML:Create()
oFileXML:Write(cTextoXML)
oFileXML:Close()

Isso me ajudou a corrigir um problema na geração do XML devido descrição de condição de pagamento:

Antes:

Negocia��o Futura

Depois:

Negociação Futura

Grato

Responder
- Dan Atilio (Daniel Atilio) disse:
  
  26 de janeiro de 2022 às 6:23 am
  
  Opa, muito obrigado pelo comentário e contribuição Josuel.
  Realmente uma ótima dica, trocar para FWFileWriter.
  Grande abraço.
  
  Responder
Thiago disse:

26 de janeiro de 2022 às 7:43 am

Essa função RetIdEnti() ela é nativa ou você implementou ela Daniel?

Responder
ThiagoM disse:

26 de janeiro de 2022 às 7:45 am

Olá, Daniel.
Tenho uma dúvida, essa função para obter o IdEnt é nativa ou você desenvolveu ela? RetIdEnti()

Responder
- Dan Atilio (Daniel Atilio) disse:
  
  28 de janeiro de 2022 às 8:46 am
  
  Bom dia Thiago, tudo bem?
  Sim ela é nativa.
  Tanto que, para verificar no seu ambiente, aperte Ctrl + Shift + P no VSCode, e vá em inspetor de funções.
  Procure pelo nome dessa função, ela estará dentro do SPEDNFE.PRX
  
  Responder
Josuel Silva disse:

26 de janeiro de 2022 às 1:42 pm

Olá @ThiagoM,
esta função é nativa e retorna o codigo da entidade que será enviado para o TSS.
Basicamente para ela relaciona o codigo que está relacionado a Filial logada.

Grato.

Responder
Rodolfo Novaes de Sousa disse:

7 de junho de 2022 às 7:33 pm

boa noite! muito boa a função!
estou com um problema, utilizando ela via menu no sigamdi funcionou perfeitamente. Porem ao fazer a chamada a partir de uma API Rest , retorna que não achou a NF “zSpedXML > Verificar parâmetros, documento e série não encontrados” .

Responder
- Dan Atilio (Daniel Atilio) disse:
  
  8 de junho de 2022 às 7:01 am
  
  Bom dia Rodolfo.
  Obrigado pelo feedback. Eu tive esse problema uma vez em REST, e era por causa que a filial não estava posicionada corretamente.
  Então para resolver, tive que usar a função OpenFile, conforme esse exemplo: https://terminaldeinformacao.com/2021/12/01/como-mudar-de-empresa-e-filial-com-a-funcao-openfile/
  
  Responder
- Altair disse:
  
  9 de janeiro de 2023 às 5:09 pm
  
  Boa tarde!
  Como faço para executar est função dentro da API?
  Grato
  
  Responder
  - Dan (Daniel Atilio) disse:
    
    10 de janeiro de 2023 às 7:25 am
    
    Bom dia Altair, tudo joia?
    
    Para acionar a chamada através de outros fontes, você deve fazer o seguinte:
```
//Gerando o XML em um arquivo dentro da Protheus Data
cDocumento := SUAQRY->F2_DOC
cSerie     := SUAQRY->F2_SERIE
cArqXML    := "\x_sua_pasta\arquivo.xml"
u_zSpedXML(cDocumento, cSerie, cArqXML)

//Lendo o conteudo do XML e jogando em uma variável (ao invés do MemoRead, também da para usar FWFileReader ou outras formas)
cConteudo := MemoRead(cArqXML)
```
    Ai a partir disso, você consegue usar essa variável cConteudo.
    
    Verifiquei aqui Altair, e você é um assinante premium, caso você queira, tem um fonte pronto de WebService com exemplo acionando a geração do xml e do pdf da Danfe, basta você acessar sua conta na Hotmart, ir em fontes premium, e no número 18 vai ter lá WebService para gerar a DANFE e o XML de uma NF. Esse é o link de exemplo desse conteúdo premium: https://terminaldeinformacao.com/2022/02/04/webservice-para-gerar-a-danfe-e-o-xml-de-uma-nf/
    
    Um grande abraço.
    
    Responder
Marcos Almeida disse:

2 de dezembro de 2022 às 7:35 am

esse webservice baixa notas que nao esteja no sped050?

Responder
- Dan (Daniel Atilio) disse:
  
  2 de dezembro de 2022 às 7:59 am
  
  Bom dia.
  Não, essa rotina é específica para Notas que já estejam na SPED050.
  Se você quer uma para baixar o XML direto do SEFAZ, recomendo verificar uma desenvolvida pelo Súlivan Simões – https://sulivansistemas.com/wp/protheus-rotina-de-download-de-xml-de-nf-e-e-ct-e/
  
  Responder
Lucas Massad disse:

27 de dezembro de 2022 às 2:54 pm

Boa tarde!
O fonte funciona caso o Protheus e o TSS estejam no Cloud do Totvs?
É necessária alguma configuração específica no TSS?

Responder
- Dan (Daniel Atilio) disse:
  
  27 de dezembro de 2022 às 3:31 pm
  
  Boa tarde Lucas, tudo joia?
  Sim, nós já implantamos em clientes que usam o TCloud.
  No caso não precisa de configuração específica, apenas o MV_SPEDURL precisa estar apontando para o TSS corretamente.
  
  Responder
Altair disse:

9 de janeiro de 2023 às 4:53 pm

Boa tarde Rodofolfo!
Com fez para chamar a fcunção a partir da API? preciso chamá-la no GET.

Responder
Douglas disse:

15 de março de 2023 às 2:51 pm

Parabéns pelo trabalho!

Responder
- Dan (Daniel Atilio) disse:
  
  16 de março de 2023 às 8:09 am
  
  Bom dia Douglas.
  Nós que agradecemos pelo comentário e feedback.
  Grande abraço.
  
  Responder
Marcos disse:

18 de outubro de 2023 às 6:53 am

Oi, bom dia. Parabéns pelo conteúdo!
Existe alguma customização para imprimir danfes canceladas?

Responder
- Dan (Daniel Atilio) disse:
  
  18 de outubro de 2023 às 7:10 am
  
  Bom dia Marcos, tudo joia?
  
  Obrigado pelo comentário e feedback.
  
  Ainda não temos, pode ser que no futuro desenvolvemos algum template.
  
  Se inscreva na nossa newsletter, que se fizermos, publicaremos um artigo divulgando.
  
  Um grande abraço.
  
  Responder
Edilson Leal disse:

24 de julho de 2024 às 11:00 am

Boa tarde,
Existe a função da TOTVS que trás o xml e outras informações em um array: GetXMLNFE(cIdEnt, aNfs, @cModalidade, )

Responder
- Dan (Daniel Atilio) disse:
  
  25 de julho de 2024 às 5:22 am
  
  Bom dia Edilson, tudo joia?
  
  Opa, show de bola, desconhecia essa GetXMLNFE, vou adicionar aqui na to-do list para estudar sobre.
  
  Tenha uma ótima e abençoada quinta feira.
  
  Um grande abraço.
  
  Responder
Adauto Júnior disse:

30 de agosto de 2024 às 2:35 pm

Boa tarde!

Consigo filtrar apenas para gerar os XMLs das notas de venda? Pq temos operações de transferências entre filiais, devoluções de compras, entre outras, que utilizam a mesma rotina.

Desde já agradeço!

Responder
- Dan (Daniel Atilio) disse:
  
  31 de agosto de 2024 às 7:02 am
  
  Bom dia Adauto, tudo joia?
  
  Sim, você consegue, mas tem que ser na função anterior sua, que irá acionar a u_zSpedXML.
  
  Por exemplo, nessa sua função anterior, você pode fazer uma query na SF2, e já filtrar o F2_TIPO antes de acionar a u_zSpedXML, nesse link tem um exemplo (veja o trecho escrito “Abaixo um Exemplo com While”: https://terminaldeinformacao.com/2019/03/02/funcao-para-gerar-danfe-e-xml-de-uma-nota-em-uma-pasta-via-advpl/
  
  Tenha um ótimo e abençoado fim de semana.
  
  Um grande abraço.
  
  Responder