Nesse vídeo demonstraremos a utilização da classe TSpinBox, que serve para criar uma caixa de texto, que na direita tenha botões para incrementar ou decrementar um valor conforme o intervalo definido.

Abaixo o código fonte desenvolvido para o exemplo em vídeo acima:

//Bibliotecas
#Include "TOTVS.ch"

/*/{Protheus.doc} User Function zExe510
Cria uma caixa de texto com botões ao lado de manipulação
@type Function
@author Atilio
@since 04/04/2023
@see https://tdn.totvs.com/display/tec/TSpinBox
@obs 

    **** Apoie nosso projeto, se inscreva em https://www.youtube.com/TerminalDeInformacao ****
/*/

User Function zExe510()
    Local aArea         := FWGetArea()
    Local nCorFundo     := RGB(238, 238, 238)
    Local nJanAltura    := 154
    Local nJanLargur    := 318 
    Local cJanTitulo    := 'Exemplo TSpinBox'
    Local lDimPixels    := .T. 
    Local lCentraliz    := .T. 
    Local nObjLinha     := 0
    Local nObjColun     := 0
    Local nObjLargu     := 0
    Local nObjAltur     := 0
    Private cFontNome   := 'Tahoma'
    Private oFontPadrao := TFont():New(cFontNome, , -12)
    Private oDialogPvt 
    Private bBlocoIni   := {|| /*fSuaFuncao()*/ } //Aqui voce pode acionar funcoes customizadas que irao ser acionadas ao abrir a dialog 
    //objeto0 
    Private oSpinBox 
    Private nSpinBox    := 10
    //objeto1 
    Private oBtnObj1 
    Private cBtnObj1    := 'Confirmar'  
    Private bBtnObj1    := {|| MsgInfo('O valor é:' + CRLF + CRLF + cValToChar(nSpinBox), 'Atenção')}  
    
    //Cria a dialog
    oDialogPvt := TDialog():New(0, 0, nJanAltura, nJanLargur, cJanTitulo, , , , , , nCorFundo, , , lDimPixels)
    
        //objeto0 - usando a classe TSpinBox
        nObjLinha := 7
        nObjColun := 6
        nObjLargu := 145
        nObjAltur := 15
        oSpinBox := TSpinBox():New(nObjLinha, nObjColun, oDialogPvt, {|x| nSpinBox := x }, nObjLargu, nObjAltur)
        oSpinBox:setRange(-30, 30)
        oSpinBox:setStep(5)
        oSpinBox:setValue(nSpinBox)

        //objeto1 - usando a classe TButton
        nObjLinha := 54
        nObjColun := 6
        nObjLargu := 75
        nObjAltur := 15
        oBtnObj1  := TButton():New(nObjLinha, nObjColun, cBtnObj1, oDialogPvt, bBtnObj1, nObjLargu, nObjAltur, , oFontPadrao, , lDimPixels)

    
    //Ativa e exibe a janela
    oDialogPvt:Activate(, , , lCentraliz, , , bBlocoIni)
    
    FWRestArea(aArea)
Return

Bom pessoal, por hoje é só.

Abraços e até próxima.

Tags: AdvPLMaratonaProtheusTL++