No artigo de hoje, vamos mostrar em como imprimir um arquivo no sistema operacional via AdvPL.

Recentemente, nos perguntaram se teria como acionar a impressão de um arquivo do Windows via AdvPL. Conseguimos fazer para arquivos com a extensão .txt.

Para a montagem desse artigo, foi usado a função padrão SendFile. A lógica da função customizada ficou a seguinte:

1. Primeiro, é feito uma busca nas impressoras instaladas através da GetImpWindows
2. Se houver, ai vamos usar a zQry2Txt para gerar um arquivo TXT com o resultado de uma query, clique aqui para baixar essa função
3. Após a geração do arquivo, será acionado a SendFile, onde será aberto uma tela para confirmar a impressão (similar a tela abaixo, usando o WebAgent com Google Chrome):

Tela de impressão via navegador

Abaixo o código fonte desenvolvido conforme a lógica descrita acima:

//Bibliotecas
#Include "Totvs.ch"

/*/{Protheus.doc} zTstPrint
Função para testar o acionamento da impressão de arquivo via impressora padrão
@type user function
@author Atilio
@since 28/04/2025
@obs Essa função ela aciona a SendFile que trabalha parecida com a PrintInWin (junto com a PreparePrint, InitPrint e PrintDriver)
/*/

User Function zTstPrint()
    Local aArea        := FWGetArea()
    Local cFolder      := ""
    Local cFileName    := ""
    Local aImpressoras := {}
    Local cFileTxt     := ""

    //Busca as impressoras
    aImpressoras := GetImpWindows(.F.)	

    //Se encontrou impressoras
    If Len(aImpressoras) > 0
        //Gera um arquivo txt conforme a query através da u_zQry2Txt
        cFileTxt := u_zQry2Txt("SELECT TOP 10 B1_COD, B1_DESC FROM " + RetSQLName("SB1"))
        cFolder := ExtractPath(cFileTxt)
        cFileName := ExtractFile(cFileTxt)

        //Envia o arquivo para a tela de confirmar a impressão
        SendFile(;
            cFileName,;       // cArquivo,;
            1,;               // nMidia,; 1 = Windows; 2 = Porta; 3=eMail
            "",;              // cPorta,;
            "",;              // cCbPortClie,;
            aImpressoras[1],; // cImpress,;
            aImpressoras[1],; // cImpCbClie,;
            ,;                // cCbDrv,;
            2,;               // nAmbiente,; 1=Server; 2=Client
            cFolder,;         // cDirAtu,;
            ,;                // cPagAtu,;
            .F.,;             // lPagAtu,; Imprime somente a página atual
            ,;                // cGetMail,;
            .F.,;             // lPagInt,; Imprime intervalo de páginas
            1,;               // nRgStart,;
            1,;               // nRgEnd,;
            0;                // nMargOpc;
        )
    EndIf
 
    FWRestArea(aArea)
Return

Bom pessoal, por hoje é só.

Abraços e até a próxima.

Tags: AdvPLProtheus